move rails app into src/, add Vagrantfile & puppet/ assets and add src/.gitignore file

puppet/modules/postgresql/manifests/db.pp

@@ -0,0 +1,20 @@
+define postgresql::db (
+    $password,
+    $owner = $name,
+    $encoding = 'UTF8',
+    $locale = 'en_US.UTF-8',
+) {
+
+    pg_user {$owner:
+        ensure      => present,
+        password    => $password,
+    }
+
+    pg_database {$name:
+        ensure      => present,
+        owner       => $owner,
+        require     => Pg_user[$owner],
+        encoding    => $encoding,
+        locale      => $locale,
+    }
+}

puppet/modules/postgresql/manifests/init.pp

@@ -0,0 +1,12 @@
+class postgresql (
+  $client_package = $postgresql::params::client_package,
+  $version = $postgresql::params::version
+
+) inherits postgresql::params {
+
+  package { "postgresql-client-$version":
+    name    => sprintf("%s-%s", $client_package, $version),
+    ensure  => present,
+  }
+
+}

puppet/modules/postgresql/manifests/params.pp

@@ -0,0 +1,15 @@
+class postgresql::params {
+  $locale = 'en_US.UTF-8'
+  case $::operatingsystem {
+    /(Ubuntu|Debian)/: {
+      $version = '9.1'
+      $client_package = 'postgresql-client'
+      $server_package = 'postgresql'
+      $listen_address = 'localhost'
+      $port = 5432
+    }
+    default: {
+      fail("Unsupported platform: ${::operatingsystem}")
+    }
+  }
+}

puppet/modules/postgresql/manifests/server.pp

@@ -0,0 +1,47 @@
+class postgresql::server (
+  $server_package = $postgresql::params::server_package,
+  $locale = $postgresql::params::locale,
+  $version = $postgresql::params::version,
+  $listen = $postgresql::params::listen_address,
+  $port = $postgresql::params::port,
+  $acl = []
+) inherits postgresql::params {
+
+  package { "postgresql-server-$version":
+    name    => sprintf("%s-%s", $server_package, $version),
+    ensure  => present,
+  }
+
+  service { "postgresql-system-$version":
+    name        => 'postgresql',
+    enable      => true,
+    ensure      => running,
+    hasstatus   => false,
+    hasrestart  => true,
+    provider    => 'debian',
+    subscribe   => Package["postgresql-server-$version"],
+  }
+
+  file { "postgresql-server-config-$version":
+    name    => "/etc/postgresql/$version/main/postgresql.conf",
+    ensure  => present,
+    content => template('postgresql/postgresql.conf.erb'),
+    owner   => 'postgres',
+    group   => 'postgres',
+    mode    => '0644',
+    require => Package["postgresql-server-$version"],
+    notify  => Service["postgresql-system-$version"],
+  }
+
+  file { "postgresql-server-hba-config-$version":
+    name    => "/etc/postgresql/$version/main/pg_hba.conf",
+    ensure  => present,
+    content => template('postgresql/pg_hba.conf.erb'),
+    owner   => 'postgres',
+    group   => 'postgres',
+    mode    => '0640',
+    require => Package["postgresql-server-$version"],
+    notify  => Service["postgresql-system-$version"],
+  }
+
+}